PC-HELP.CZ

Ahoj,
poradí někdo s tím, jak má ve VB excelu vypadat generovaný email po stisku tlačítka? Nevím, jestli tak (viz příloha) je to nejlépe psané. Jak má v tělu emailu vypadat, když chci poslat odkaz? Šlo by v předmětu nebo tělu emailu vložit kód, aby se generoval automaticky vložený dnešní den (př.6.6.2010)? Jak by mělo vypadat napsání odkazu? Viz příloha a záložka odkaz, to kdybych tam chtěl vložit….aby vždycky odkaz na soubor bral z aktuální umístěné složky, kde bude i uložen tento soubor(složka uložení se každý den mění,proto odkazuje na soubory,uložené s tímto souborem,kde se názvy nemění)…. a je jednoduché aby se vložil i nějaká část do emailu z přiloženého excelu? nenašel jsem moc na internetu jak psát právě „generovaný“ email….
Díky

Vhodna procedura by mohla treba vypadat takto (netestoval jsem, je vedro na padnuti - 33 ve stinu, snad se doplazim k pivu), v editoru VBA vloz do modulu listu obsahujiciho tlacitko (prikazove tlacitko vloz z Ovladacich prvku, nikoliv Formulare, tlacitko ma nazev cmdSendMail):

Kód: Vybrat vše

Option Explicit

Private Sub cmdSendMail_Click()

  Dim ol As Object
  Dim myItem As Object
  Dim adresat As String, kopie As String, predmet As String, telo As String
  Dim katalog As String, Clls() As Variant, i As Byte, j As Byte

  Set ol = CreateObject("outlook.application")
  Set myItem = ol.CreateItem(0)
  adresat = "yyy@yyy.cz"
  kopie = "xxx@xxx.cz"
  predmet = "Ranní stav: " & Now  ' pridan casovy udaj
  Clls = Me.Range("b7:d11").Value  ' pole bunek z listu
  katalog = ActiveWorkbook.Path & "\"  ' aktualni katalog pro pripojeny soubor
  telo = "Ahoj, posílám dnešní ranní stav" & vbCrLf & vbCrLf  ' prvni cast zpravy
  ' do tela pridat obsah z bunek b7:d11
  For i = 1 To UBound(Clls, 1)
    For j = 1 To UBound(Clls, 2)
      telo = telo & Clls(i, j) & vbTab
    Next j
    telo = telo & vbCrLf
  Next i
  With myItem
    .To = adresat
    .CC = kopie
    .Subject = predmet
    .Body = telo
    .Attachments.Add katalog & "nazev" & ".xlsx" ' pripojit soubor
    .NoAging = True
    .ReadReceiptRequested = True
    .OriginatorDeliveryReportRequested = True
    .display
    .send
  End With
  Set ol = Nothing
  Set myItem = Nothing
End Sub

Kdyz zadas do vyhledavace CreateObject("outlook.application"), dostanes radu odkazu (Google i prelozi) resicich tuto problematiku

Ahoj,
zítra zkusím v práci, ale předem moc dík

jo,jo,vedro je pekelné

tak díky moc, fungovalo to, zbytek si najdu na netu, jak si psal, díík

PC-HELP.CZ

VB a email

VB a email Vyřešeno

Re: VB a email

Re: VB a email

Re: VB a email