Program na zálohu souborů minecraft Windows

...

Moderátor: Mods_senior

Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 01 led 2021 15:53

Dobrý den. Potřebuji si nechat trošku od vás poradit. Mám na Windows Serveru puštěný minecraft už pár dní, ale vzjistila jsem menší zádrhel a to je to, že prostě nemám jak zálohovat mc potřebuji nějaký program co to zálohuje a následně pošle třeba na google DISK. Nebo to bude ukládat lokálně. Předem díky.

Reklama
Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Re: Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 02 led 2021 17:26

UP

Uživatelský avatar
ITCrowd
Tvůrce článků
Guru Level 13
Guru Level 13
Příspěvky: 21514
Registrován: březen 10
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod ITCrowd » 02 led 2021 19:43

Ahoj,
pokud víš jaké přesně soubory a adresáře se mají zálohovat, můžu na to napsat skript ve vbs.
Něco podobného jsem psal tady: viewtopic.php?f=61&t=108965
Zkusili jste to vypnout a zapnout? Problémy řeším pouze v tématech. Do SZ mi proto píšete zbytečně.
Základní diagnostika WiFi Jak na diagnostiku sítě Router jako switch Proč je nesmysl chtít router s velkým dosahem Vybíráme router

Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Re: Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 04 led 2021 09:16

Zde jso uvšechny soubory Minecraftu, které je třeba pokaždé zálohovat. Záloha se alespoň by měla podle mně jak to kdysi hicoria měla dělat co 4 hodiny, jelikož nevíme zda někdo něco nezničí nebo hacker nezaútočí. Jako před dvěmi měsíci se nám toto stal os hackerem.

1.Všechny zálohy poputují na vzdálení disk, který je propojený 192.168.1.2 veřejnou ip adresu sem dávat nebudu. Jelikož to je propojené obouma variantami, ale 192 je přes vnitřní páteřní síť.
2.Disk na zálohy je s označením F:
3. V pc mám pouze uživatele což jsem já s jménem CloudGirl,
Nemáte oprávnění prohlížet přiložené soubory.

Uživatelský avatar
ITCrowd
Tvůrce článků
Guru Level 13
Guru Level 13
Příspěvky: 21514
Registrován: březen 10
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod ITCrowd » 04 led 2021 10:08

Takže chceš zálohovat vše ve složce Minecraft server? Chápu to dobře? V tom případě potřebuji absolutní cestu k složce Minecraft server.
A chceš to na F: (což je namapovaná síťová složka jako disk)?
K časování - skript vložíš do plánovače úloh. Tam si můžeš nastavit jak četnost spouštění, tak účet, pod kterým poběží. Samozřejmě ten účet musí mít přístup k F:.
Máš na tom serveru nainstalovaný nějaký pakovač (zip, rar)? Skript by mohl celý ten adresář zabalit.
Zkusili jste to vypnout a zapnout? Problémy řeším pouze v tématech. Do SZ mi proto píšete zbytečně.
Základní diagnostika WiFi Jak na diagnostiku sítě Router jako switch Proč je nesmysl chtít router s velkým dosahem Vybíráme router

Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Re: Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 04 led 2021 16:11

Ano celý adresář souborů: C:\Users\CloudGirl\Desktop\Minecraft server
F: Je namapovaný jako disk .
A ano mám tam Winrar nainstalovaný
účty mi běží přes Doménu, takže kdekoliv se mohu připojit za účet jako CloudGirl.

Uživatelský avatar
ITCrowd
Tvůrce článků
Guru Level 13
Guru Level 13
Příspěvky: 21514
Registrován: březen 10
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod ITCrowd » 04 led 2021 16:20

OK. Pustím se do toho.
Zkusili jste to vypnout a zapnout? Problémy řeším pouze v tématech. Do SZ mi proto píšete zbytečně.
Základní diagnostika WiFi Jak na diagnostiku sítě Router jako switch Proč je nesmysl chtít router s velkým dosahem Vybíráme router

Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Re: Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 05 led 2021 14:29

OKI :) Díky moc

Uživatelský avatar
ITCrowd
Tvůrce článků
Guru Level 13
Guru Level 13
Příspěvky: 21514
Registrován: březen 10
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod ITCrowd » 07 led 2021 10:15

Ahoj,
bude to trochu složitější :-)
Nejdřív je třeba v proměnné path nastavit cestu k adresáři WinRar (pokud není). Pravoklik na počítač, vlastnosti.
WinrarPATH.png


Vlastní skript:

Kód: Vybrat vše

'***********************************************************
'*   Script kopíruje všechny soubory a složky MineCraft    *
'*       Vytváří si soubory na síťovém disku               *
'***********************************************************
'*            Vytvořeno pro PC-HELP                        *
'*                Etienn@Script                            *
'***********************************************************


Option Explicit
Dim Mesic, Den, Hodina, NameFile, rarName, WshShell, fso, txtStream, cesta
Dim prikaz, ReturnCode, ForAppend, cil, zdroj

cil = "F:\MCzal\"
zdroj = "C:\Users\CloudGirl\Desktop\Minecraft server\"
Const LogFile = "C:\ScriptLog\zallog.txt"

' vytvoreni nazvu souboru
Mesic = Month(Now())
Den = Day(Now())
Hodina = Hour(Now())
If Hodina < 10 Then Hodina = "0" & Hodina
If Den < 10 Then Den = "0" & Den
If Mesic < 10 Then Mesic = "0" & Mesic
Namefile = "MineCraft" & "_" & Year(Now()) & Mesic & Den & Hodina & ".rar"
rarName = "MineCraft" & "_" & Year(Now()) & Mesic & Den & Hodina
'WScript.Echo Namefile
'WScript.Echo rarName

' Nastaveni objektu a adresare s logy
ForAppend = 8
Set WshShell = WScript.CreateObject("WScript.Shell")
Set fso = CreateObject("Scripting.FilesystemObject")
If (Not fso.FolderExists("C:\ScriptLog")) Then fso.CreateFolder("C:\ScriptLog")
Set txtStream = fso.OpenTextFile(LogFile, ForAppend, True)

' adresar existuje? If not - create
If (Not fso.FolderExists(cil)) Then fso.CreateFolder(cil)

' existuje jiz zaloha?
cesta = cil & Namefile
If fso.FileExists(cesta) Then
   txtStream.WriteLine Date & vbTab &Time & vbTab & "Soubor zálohy již existuje"
   txtStream.Close   
   Set WshShell = Nothing
   Set fso = Nothing
   Set txtStream = Nothing
   WScript.Quit
End If

' provedeni zalohy
zdroj = zdroj & "*.*"
rarName = cil & rarName
WScript.Sleep 500
'prikaz = "winrar a " & rarName & " -m5 -tsca -ac -ilog " & zdroj
prikaz = "winrar a -r -m5 -tsca -ac -ilog " & rarName & " " & zdroj
ReturnCode = WshShell.Run(prikaz, 1, True)
WScript.Sleep 2000

'Test zda zaloha probehla v poradku
If ReturnCode = 0 Then
   txtStream.WriteLine Date & vbTab & Time & vbTab & "Záloha proběhla v pořádku"
   txtStream.Close
Else
   txtStream.WriteLine Date & vbTab & Time & vbTab & "Záloha se nepodařila" & vbTab & "Kód: " & ReturnCode
   txtStream.Close
End If

Set WshShell = Nothing
Set fso = Nothing
Set txtStream = Nothing


Zkopíruj text v code, vlož do notepadu (nepoužívat word) a ulož s příponou .vbs.
V naplánovaných úlohách si pak nastav, kdy chceš skript spouštět.

význam proměnných:
zdroj - absolutní cesta k adresáři, který má být zálohován
cíl - absolutní cesta k adresáři, kam jsou vytvářeny zálohy. Síťový disk musí být přístupný. Pokud adresář neexistuje, skript si ho vytvoří.
LogFile - absolutní cesta k souboru logů - skript svou činnost loguje a výsledek zapisuje, včetně případného chybového kódu winraru. Pokud adresář a soubor neexistuje, vytvoří si je. POZOR - pokud budeš chtít logy jinde, než je nastaveno, je třeba změnit složku i v tomto řádku:If (Not fso.FolderExists("C:\ScriptLog")) Then fso.CreateFolder("C:\ScriptLog")
Skript zabalí celou adresářovou strukturu tak jak je, včetně podadresářů. Vytváří název zálohy ve formátu MineCraft_RRRRMMDDHH.rar.
Skript si kontroluje, zda záloha již neexistuje, pokud ano, zapíše do logu.
Skript lze samozřejmě spustit ručně (poklepáním).
Nemáte oprávnění prohlížet přiložené soubory.
Zkusili jste to vypnout a zapnout? Problémy řeším pouze v tématech. Do SZ mi proto píšete zbytečně.
Základní diagnostika WiFi Jak na diagnostiku sítě Router jako switch Proč je nesmysl chtít router s velkým dosahem Vybíráme router

Gasour
Level 1
Level 1
Příspěvky: 89
Registrován: srpen 15
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod Gasour » 07 led 2021 10:36

Základní zálohování na souborové úrovni můžeš použít starší prográmek Cobian.
https://www.cobiansoft.com/cobianbackup.html

Pokud hledáš něco sofistikovanějšího tak veeam
Veeam Agent pro Microsoft Windows FREE
https://www.veeam.com/cz/downloads.html

Uživatelský avatar
AngelikaB
Level 5.5
Level 5.5
Příspěvky: 3078
Registrován: červen 13
Pohlaví: Žena

Re: Program na zálohu souborů minecraft Windows

Příspěvekod AngelikaB » 07 led 2021 12:55

07.01.2021 12:54:15 Záloha se nepodařila Kód: 10
07.01.2021 12:54:35 Záloha se nepodařila Kód: 10


A winrar se pustil a nic ... V F: se vytvořila složka MCzal.

Dodatečně přidáno po 27 minutách 35 vteřinách:
Tak jsem dala pryč toto: \ zalohovalo mi to jen CloudGirl něco něco. A pak Minecraft ale jen pluginy a nic víc. Takže bude asi chyba někde ve skriptu..

+ Lze udělat tak ať se vytvoří nová záloha další. Já je pak po týdnu budu mazat

Uživatelský avatar
ITCrowd
Tvůrce článků
Guru Level 13
Guru Level 13
Příspěvky: 21514
Registrován: březen 10
Pohlaví: Muž

Re: Program na zálohu souborů minecraft Windows

Příspěvekod ITCrowd » 07 led 2021 13:25

Jasně - mezera :-)
Omluva :-)
Uprav tento řádek:

Kód: Vybrat vše

zdroj = "C:\Users\CloudGirl\Desktop\Minecraft server\"
na

Kód: Vybrat vše

zdroj = """C:\Users\CloudGirl\Desktop\Minecraft server\"""

"+ Lze udělat tak ať se vytvoří nová záloha další. Já je pak po týdnu budu mazat" nepředpokládá se, že bys dělala zálohu častěji, než jednou za hodinu. Protože je hodina součást jména, pak skript soubor zálohy v další hodině nenajde a vytvoří nový. Pro testování klidně již vytvořenou zálohu smaž (popřípadě ho můžeš přejmenovat).
Skript si vytváří jméno souboru v proměnné NameFile ve formátu MineCraft_RRRRMMDDHH.rar - ten potom kontroluje, zda existuje. RRRRMMDDHH je aktuální datum a hodina v čase spuštění skriptu.
Zkusili jste to vypnout a zapnout? Problémy řeším pouze v tématech. Do SZ mi proto píšete zbytečně.
Základní diagnostika WiFi Jak na diagnostiku sítě Router jako switch Proč je nesmysl chtít router s velkým dosahem Vybíráme router


  • Mohlo by vás zajímat
    Odpovědi
    Zobrazení
    Poslední příspěvek
  • Jak obnovit zálohu Windows po výměně komponentů ?
    od jkmaxfli » 22 lis 2020 18:44 » v Windows 10, 8, 7..
    51
    2717
    od jkmaxfli
    28 lis 2020 16:07
  • Jde na Windows XP udělat minecraft server?
    od BuffaloDC » 09 dub 2021 09:37 » v Vše ostatní (hw)
    1
    363
    od mmmartin
    09 dub 2021 09:53
  • externí disk na zálohu 1TB
    od mafian » 12 říj 2021 10:19 » v Rady s výběrem hw a sestavením PC
    1
    109
    od atari
    12 říj 2021 10:24
  • Jaký spolehlivý 2TB hdd na zálohu
    od RagX » 22 lis 2020 18:44 » v Rady s výběrem hw a sestavením PC
    8
    589
    od petr22
    22 lis 2020 22:09
  • Windows Insider Program - Je nebezpečný?
    od RayCodeCSC » 29 čer 2021 22:46 » v Windows 10, 8, 7..
    1
    178
    od petr22
    29 čer 2021 22:49

Zpět na “Vše ostatní (sw)”

Kdo je online

Uživatelé prohlížející si toto fórum: CommonCrawl [Bot] a 1 host