Vytvoření programu

[Programzero]

Ahoj, jednou jsem si takhle řekl že bych si pro svoji vymyšlenou zatím nedokončenou hru launcher bez netu.
Chtěl bych aby to vypadalo jako příkazový řádek. Z nějakého zdroje v PC. Když bych ho zapnul vyjelo by login: nick se tam zada
a pote Password: to heslo k uctu pote by mi to napsalo Vitej pouzij help a napsal bych help a oni by se tam vypsali prikazy atd. poradite mi prosííííím někdo? Jestli se Vám to někomu podařá mi naspat tak ho budu hned jak dokončím hru střílečku s dobrou grafikou tak ho budu kontaktovat. Prosím poraďte

--- Doplnění předchozího příspěvku (01 Srp 2011 14:18) ---

Sry za hrubky oprava nejvetsich hrubek : Ahoj, jednou jsem si takhle řekl že bych si pro svoji vymyšlenou zatím nedokončenou hru VYROBÍM launcher bez netu. dalsi Password: ZADÁM to heslo k uctu A pote by mi to napsalo Vitej pouzij help

[Reklama]

[Pic]

Co takhle napsat to ve smyslu plných českých větách. Kdo to má luštit. To chceš programovat - když tam záleží na každé mezeře, tečce, čárce atd.?

[faraon]

Chybí mi tu pár podstatných informací, jako třeba v jakém jazyce to programuješ, kde budou uložená jména a hesla hráčů, nebo jak ten launcher bude s tou tvojí hrou spolupracovat...
Nejjednodušší (a pro tebe asi nejméně použitelný) způsob co mě napadá je vytvořit to v BASICu:

Kód: Vybrat vše

10 print ">>> Game Launcher <<<"
20   input "User login: ",u$
30   input "Password: ",p$
40   restore 1000
50   read l$,h$
60   if l$="" then print chr$(7)+"Neznamy uzivatel!":goto 10
70   if u$=l$ and p$=h$ then goto 90
80 goto 50
90 print "Vitej, pouzij 'help'."

100 print "#> ";
110   line input "",c$
120   if c$="help" then goto 2000
130   if c$="exit" then goto 200
140   if c$="end" then goto 300
150   print chr$(7)+"Neznamy prikaz, pouzij 'help'!"
160 goto 100

200 print "Loucim se s tebou, stiskni klavesu..."
210 if inkey$="" then goto 210
220 cls
230 goto 10

300 input "Opravdu chces ukoncit program? (A/N) ",v$
310   if v$="n" or v$="N" then goto 100
320   if v$="a" or v$="A" then goto 350
330   print "Chybna volba!"
340 goto 300
350 print "Konec programu."
360 new

1000 data "jirka","okurka"
1010 data "honza","12345"
1020 data "petra","kopretina"
1100 data "",""

2000 restore 2100
2010 for i=1 to 3
2020   read p$,h$
2030   print p$
2040   print h$
2050 print
2060 next i
2070 goto 100
2100 data "help","vypise tuto napovedu"
2110 data "exit","odhlasi uzivatele a ceka na prihlaseni dalsiho"
2120 data "end","ukonci program a vymaze ho z pameti"

Není to moc dobře napsané, jen rychlovka na ukázku, takže například jména a hesla uživatelů najdeš na řádcích 1000 až 1020, místo toho aby správně byla uložená ve zvláštním souboru a šifrovaná.
Odzkoušet to můžeš třeba tady: http://telehack.com/ Napiš tam příkaz basic, spusť ho a přepiš tam ten můj kód, odstartuješ ho příkazem run. Ale musíš ho opsat přesně tak jak je a bez překlepů!
Také se tam můžeš inspirovat, najdeš na té stránce spoustu zajímavých věcí, například hromadu starých her, a žádná z nich nemá vůbec žádnou grafiku

Ale mám pocit že by sis měl nejdřív prostudovat tyhle dvě stránky:
http://cs.wikipedia.org/wiki/Programov%C3%A1n%C3%AD
http://cs.wikipedia.org/wiki/Programovac%C3%AD_jazyk

[SimiX-[Poradím]]

ahoj ja bych chtěl taki vědět např.. jak si vytvořit svojí hru jake programy jsou na to dobre atd. díky

[mar00m]

SimiX-[..... : Založ si své vlastní téma. Přečti si pravidla