Excel 2016 - vzorec kombinace podmínek

[MK_Vs]

Dobrý den,
potřebuji vytvořit jeden souhrnný vzorec (viz 4) v Excel 2016; kdy budou zohledněny následující podmínky.

Pro jednotlivé kroky jsem si postupně rozepsal vzorce, viz příloha, nedaří se mě je však kombinovat v jeden.

1) Když sloupce B a C jsou prázdné a zároveň sloupce D a E obsahují číslo; porovnej pouze sloupce D a E s hodnotami minimum a maximum. V případě prázdých sloupců zobraz prázdnou buňku.
Zobraz výsledek "o" pro hodnotu v rozsahu nebo "x" pro hodnotu mimo rozsah.
- funguje

2) Když sloupce B a C obsahují číslo a zároveň sloupce D a E jsou prázdné; porovnej pouze sloupce B a C s hodnotami minimum a maximum. V případě prázdých sloupců zobraz prázdnou buňku.
Zobraz výsledek "o" pro hodnotu v rozsahu nebo "x" pro hodnotu mimo rozsah.
- funguje

3) Když sloupce B; C; D; E obsahují číslo; porovnej všechny sloupce s hodnotami minimum a maximum.
V případě prázdých sloupců zobraz prázdnou buňku.
Zobraz výsledek "o" pro hodnotu v rozsahu nebo "x" pro hodnotu mimo rozsah.
- funguje

4) Zkombinovat situace (vzorce) z příkladů 1-3 do jednoho.
- nefunguje

Situace 4 mi však nefunguje správně. Předpokládám, že dělám logickou, chybu, avšak se mi ji nedaří odhalit.
Rád budu také vědět, kde jsem logicky udělal chybu.

Prosím pomoc.

Děkuji

[Reklama]

[elninoslov]

Snáď som to obsiahol všetko (lebo tých možností je viac, napr. v každej dvojici jedno číslo, alebo iba jedna dvojica má jedno číslo, ...)

Kód: Vybrat vše

=CHOOSE(COUNT(B5:E5)+1;"";"x";IF(OR(AND(COUNT(B5:C5)=2;MIN(B5:C5)>=$B$1;MAX(B5:C5)<=$C$1);AND(COUNT(D5:E5)=2;MIN(D5:E5)>=$B$1;MAX(D5:E5)<=$C$1));"o";"x");"x";IF(AND(MIN(B5:E5)>=$B$1;MAX(B5:E5)<=$C$1);"o";"x"))
=ZVOLIT(POČET(B5:E5)+1;"";"x";KDYŽ(NEBO(A(POČET(B5:C5)=2;MIN(B5:C5)>=$B$1;MAX(B5:C5)<=$C$1);A(POČET(D5:E5)=2;MIN(D5:E5)>=$B$1;MAX(D5:E5)<=$C$1));"o";"x");"x";KDYŽ(A(MIN(B5:E5)>=$B$1;MAX(B5:E5)<=$C$1);"o";"x"))

[MK_Vs]

Dobrý den,
děkuji za pomoc. Přiznám se, že o funkci Vybrat jsem nevěděl.
Pokusil jsem se řešení upravit na variantu, kde jsou pouze 2 sloupce.

Zadání je vlastně stejné.
- oba prázdné = prázdná buňka
- B4 číslo, C4 prázdné = porveď vyhodnocení
- B4 prázné, C4 číslo = proveď vyhodnocení
- B4 číslo, C4 číslo = proveď vyhodnocení
Nepochodil jsem. Funguje jen na prázdné buňky.
V příloze příspěvku jsem vložil dokument Vzorec_prac_2.xlsx, kde je můj pokus.

Prakticky totéž jsem zjistil, že mohu potřeovat i pro 3 sloupce B4; C4; D4, které mohu také v určitém případě vyhodnocovat.
Po předchozí zkušenosti, jsem se do pokus tvorby pro 3 sloupce zatím nepouštěl. Matou mě v půdovním řešení páry hodnot, které se kterými se pracovalo Zde je hodnota jen jedna.

Prosím, pokud je možno o pomoc a korekci.
Děkuji za Vaši pomoc.

[elninoslov]

Ja Vám nerozumiem. Nastáva množstvo kombinácií. Tu som manuálne z hlavy vypotil kombinácie, ktoré nastanú pri 2 stĺpcoch. Doplňte do nich, aký majú mať výsledok.
Vôbec nechápem, čo chcete ako porovnávať, keď v prípade 4 stĺpcov hovoríte o dvojiciach (BC)(DE), v prípade 2 stĺpcov ale chcete vyhodnocovať aj keď je zadaný iba jeden údaj, čo je nezmysel ak sa má jednať o dvojice čísel. A už vôbec nepoberám dvojice v 3 stĺpcoch. Na to sa ani nepokúšam robiť tabuľku všetkých možných variácií. To mi popíšte slovami a príkladmi.

Vzorce budem riešiť, až po pochopení problematiky.

[MK_Vs]

DObrý den,
děkuji za odpověď. Jde o to, že někdy provádím sběr dat v párech, pro dané měření. Párů může být několik a ne vždy jsou vyplněny všechny.
V jiných případech pak mám, jako napříkladu se 2 či třemi sloupci hodotu pouze jednu pro dané měření. Nemusím však vždy vyplnit vše.
Vždy záleží, na kolika zařízeních vyrábím.
Vím, že se toto může zdát chaotické, přesto más své opodstatnění a logiku v získávání dat, která následně vyhodnocuji.

[lubo.]

Ono se to nezdá, ono to chaotické je:

Ke druhému příkladu vzorec s komentářema:

Kód: Vybrat vše

=ZVOLIT(
    POČET(B8:C8) + 1;
    "";                                // obě buňky prázdné
    "x";            // v jedné buňce je číslo
    KDYŽ(            // 2 čísla
        NEBO(
            A(
                POČET(B8:C8) = 2;              // zbytečné, to je tady vždy pravda, vybráno, protože máme dvě čísla
                MIN(B8:C8) >= $B$1;
                MAX(B8:C8) <= $C$1
            );
            A(POČET(B8) = 2; MIN(B8) >= $B$1; MAX(B8) <= $C$1)   // zbytečné, vždy nepravda, v jedné buňce 2 hodnoty nebývají
        );
        "o";
        "x"
    );
    "x";               // ve dvou? buňkách tři hodnoty ?????   
    KDYŽ(A(MIN(B8:C8) >= $B$1; MAX(B8:C8) <= $C$1); "o"; "x") // ve dvou buňkách 4 hodnoty ????
)

Pokud odstraním zbytečný kód, zbude:

Kód: Vybrat vše

=ZVOLIT(
    POČET(B8:C8) + 1;
    "";
    "x";
    KDYŽ(A(MIN(B8:C8) >= $B$1; MAX(B8:C8) <= $C$1); "o"; "x")
)

Zkuste si ty vzorce trochu naformátovat. (Free webová verze excelu nabízí doplněk "Excel Labs")