V jakém jazyku začít programovat?* Vyřešeno

[honza007100]

To jsem vyřešil, jak teď pokračovat? Už nějaký ten primitivní jazyk?

[Reklama]

[faraon]

Pascal:

Kód: Vybrat vše

program hello;

begin
      writeln('Hello World!');
      readln
end.


Nainstalovat překladač, zapnout, napsat zdrojový kód, uložit do adresáře Pascal, zkompilovat, spustit. Ať se naučíš pracovat s tvým IDE.

[TheSkeleton]

Chybí ti ; za readln

[honza007100]

Hotovo, co teď?

[TheSkeleton]

Koupil bych si knihu a začal se učit :-)

[domitea]

Zkus si v pascalu udělat kalkulačku (primitivní), naučíš se používat proměnné, podmínky a cykly na výpočet mocniny.

Google poradí.....

[honza007100]

Dobře, budu se teda učit Pascal

[Fox8]

Dají se udělat v pascalu docela dobré hodiny jako spořič ...To už je ale grafika pascalu. Jinak mam tady nějake funkční programy pascalu :) kdyby jsi chtěl ...

Kód: Vybrat vše

uses crt,dos,graph;

const pi=3.14;
      velikost_hodin=100;

var   xs,ys:integer;
          x:byte;

procedure init_graph; {spusteni grafiky}
var grDriver: Integer;
      grMode: Integer;
     ErrCode: Integer;
  begin
       grDriver := Detect;
       InitGraph(grDriver, grMode,' ');
       ErrCode := GraphResult;
       if not(ErrCode = grOk) then
         begin
              Writeln('Chyba grafiky: ', GraphErrorMsg(ErrCode));
              halt(0);
         end;
  end;

procedure close_graph; {vypnuti gragiky}
  begin
       closegraph;
  end;

procedure Urci_Bod(xs,ys:integer;var xk,yk:integer;uhel,delka:integer); {spocita polohu bodu na kruznici o polomeru delka}
var uh:real;   {se souradnicemi stredu xs,ys. xk,yk jsou navratove hodnoty. uhel je uhel pom.primky od stredu do spoc.bodu}
  begin
       uh:=uhel*(pi/180);
       xk:=round(sin(uh)*delka)+xs;
       yk:=round(cos(uh)*delka)+ys;
  end;

procedure Rucicka(xs,ys,delka,uhel:integer;barva:byte); {vykresli rucicku o tveru kosouhelniku v danem uhlu, delce a barve}
var x1,y1:integer; {souradnice spicky rucicky}
    x2,y2:integer; {sour. stredoveho rozsireni}
    x3,y3:integer; { ---"---}
  begin
       Urci_Bod(xs,ys,x1,y1,uhel,delka);
       Urci_Bod(xs,ys,x2,y2,uhel+5,trunc(delka/2));
       Urci_Bod(xs,ys,x3,y3,uhel-5,trunc(delka/2));
       SetColor(barva);
       line(xs,ys,x2,y2);
       line(x2,y2,x1,y1);
       line(x1,y1,x3,y3);
       line(x3,y3,xs,ys);
  end;

Procedure Mala_Rucicka(xs,ys:integer;hod,minuta,barva:byte); {hodinova}
var uhel:integer;
  begin
       if hod>12 then hod:=trunc(hod/2); {korekce 24 hodinoveho cyklu}
       hod:=(hod+6);           {otoceni hodin o 180 stupnu}
       uhel:=(12-(hod*30))-13; {1 hod je 30stupnu na kruznici,12- otoceni chodu hodin, -13 korekce pootoceni}
       uhel:=uhel-trunc(minuta*(30/60)); {u hodinove rucicky musime zohlednit i minuty: 1 minuta je 1/60 z velikosti 1 hodiny}
       Rucicka(xs,ys,trunc(velikost_hodin/3)-2,uhel,barva);
  end;

Procedure Velka_Rucicka(xs,ys:integer;minuta,barva:byte); {minutova}
var uhel:integer;
  begin
       Minuta:=Minuta+180;  {otoceni o 180 stupnu}
       uhel:=180-(minuta*6);{zmena smyslu otaceni}
       Rucicka(xs,ys,trunc(velikost_hodin/2)-2,uhel,barva);
  end;

Procedure Vterinova_Rucicka(xs,ys:integer;sec,barva:byte); {vterinovka}
var uhel:integer;
   xp,yp:integer;
  begin
       Sec:=sec+180;
       uhel:=180-(sec*6);
       Urci_Bod(xs,ys,xp,yp,uhel,trunc(velikost_hodin/2)-1);
       SetColor(barva);
       Line(xs,ys,xp,yp);
  end;

procedure Cifernik;  {vykresli cifernik hodin}
var uhel: integer;
       x: byte;
   xp,yp: integer;
  begin
       setcolor(white);
       circle(xs,ys,2);
       circle(xs,ys,trunc(velikost_hodin/2)+2);
       for x:=0 to 3 do  {vykresleni znacek na 3,6,9,12 hod}
         begin
              Urci_Bod(xs,ys,xp,yp,x*90,trunc(velikost_hodin/2)+3);
              PutPixel(xp,yp,white+blink);
              Urci_Bod(xs,ys,xp,yp,x*90,trunc(velikost_hodin/2)+4);
              PutPixel(xp,yp,white+blink);
         end;
  end;

Procedure Refresh_Hodin; {smaze gr. obrazovku a znovu vykresli hodiny s akt. casem}
var hod,min,sec,dsec:word;
  begin
       ClearDevice;
       Cifernik;
       GetTime(hod,min,sec,dsec);
       Velka_Rucicka(xs,ys,min,yellow);
       Mala_Rucicka(xs,ys,hod,min,cyan);
       Vterinova_Rucicka(xs,ys,sec,white);
  end;


begin
     Init_Graph;
     delay(1000);
     xs:=100; ys:=100;
     repeat
           if x=20 then {vzdy po 20cyklech zmeni souradnice stredu}
             begin
                  xs:=random(300)+50;
                  ys:=random(300)+50;
                  x:=0;
             end;
           x:=x+1;
           Refresh_Hodin;
           delay(100);
     until keypressed;
     Close_Graph;
end.

[faraon]

Chybí ti ; za readln

Právě že nechybí, tohle není Céčko. V Pascalu se příkazy středníkem neukončují, ale oddělují. Například středník před else je dokonce kritická chyba!

honza007100: Teď je čas na tu učebnici, na netu sice najdeš spoustu tutoriálů, ale většinou nestojí za nic, pokud to nejsou třeba skripta nějakého profesora.

Fox8: Bude to fungovat ve FreePascalu pod Vistou nebo W7? Ale program je to pěkný, připomněl jsi mi jak jsem podobný dělal kdysi v BASICu na Didaktiku Gama. Zlaté časy...

[Fox8]

Tady je exe těch hodin jiank aby ti fungovala grafika na pascal musiš mít EGAVGA.BGI ve složce kde mas program jinak ti to nepošlape...

Exe sobor mi na W7 64bit nejde ale kompatibilitu jsem nezkoušel

[556996324]

Ve free pascalu mi to readln funguje se středníkem i bez něj

[faraon]

556996324: To je správně, překladač má za středníkem v takovém případě "prázdný" příkaz, takže se program normálně přeloží. Ale pokud bys napsal tohle:

Kód: Vybrat vše

if a=b then
   writeln('Čísla jsou stejná.');
else
   writeln('Čísla jsou různá!')


tak tím středníkem ukončíš ono if a překladač už nemá else k čemu připojit, tudíž se překlad ukončí s chybou.
Celý příkaz je
if _podmínka_ then _příkaz1_ else _příkaz2_
a středník může být teprve až za ním, pokud je třeba -> pokud následuje další příkaz.